试试下面这段代码：

import win.ui;
/*DSG{{*/
var winform = win.form(text="aardio form";right=423;bottom=469)
winform.add(
plus={cls="plus";left=8;top=8;right=388;bottom=464;bgcolor=16777215;db=1;dl=1;dr=1;dt=1;notify=1;z=1};
scrollbar={cls="scrollbar";left=392;top=8;right=416;bottom=464;db=1;dr=1;dt=1;edge=1;z=2}
)
/*}}*/

winform.show();

import godking.customPlus
var imgs = ..godking.paint.splitImage("https://aardio.online/upload/files/20250124/1737691906.png",10,10,0,0,0,0);

if godking.customPlus._version<4.3 error(" 请升级 godking.customPlus 库至最新版（不低于4.3）")
var dpi = godking.customPlus.getDpi();
var pen_black = ..gdip.pen(0xFFbbbbbb, 1*dpi);
pen_black.dashStyle = 1/*_DashStyleDot*/;
var pen_red = ..gdip.pen(0xFFFF0000, 1*dpi);
pen_red.dashStyle = 1/*_DashStyleDot*/;
var cp;
var itemModel = {
    {
        type = "rect",
        name = "bk";
        rectf = {x = 0;y = 0;width = 380;height = 40}
    } {
        type = "img", 
        rectf = {x = 5;y = 5;width = 30;height = 30}, 
        name = "logo", 
        scale = 1, /* 缩放方式 0：原尺寸居中；1：按比例填满；2：拉伸填满；3:缩到合适 */
        thumbnail = true, /*当图片宽度大于绘制宽度时，自动生成缩略图绘制。 */
    } {
        type = "text", 
        rectf = {x = 40;y = 0;width = 100;height = 40},
        name = "name", 
        cur = 32649, 
        click = true, 
        align = 1, /* 文本水平对齐方式。0、(近端)左对齐  1、居中  2、(远端)右对齐 */
        valign = 1, /* 文本垂直对齐方式。0、(近端)顶对齐  1、居中  2、(远端)底对齐 */
        font = { name = "宋体", h = 14, color = 0xFFFF0000, underline = 1},
        hoverfont = {name = "宋体", h = 14, color = 0xFF000000, underline = 1} /* 鼠标划过元素时字体 */
    } {
        type = "img",
        rectf = {x = 135;y = 5;width = 30;height = 30}, 
        name = "sex", 
        scale = 3, /* 缩放方式 0：原尺寸居中；1：按比例填满；2：拉伸填满；3:缩到合适 */
        thumbnail = true, /*当图片宽度大于绘制宽度时，自动生成缩略图绘制。 */
    } {
        type = "text", 
        rectf = {x = 180;y = 0;width = 40;height = 25},
        name = "age"
    } {
        type = "rect",
        rectf = {x = 279;y = 12;width = 16;height = 16}, 
        color = 0xFF888888;
    } {
        type = "img",
        rectf = {x = 280;y = 13;width = 14;height = 14}, 
        name = "checked", 
        click = true; /* 是否响应鼠标点击事件 */
        check = true; /* 原素是否可选择。依赖name和click。鼠标点击元素，改变元素选择状态 */
        scale = 1, /* 缩放方式 0：原尺寸居中；1：按比例填满；2：拉伸填满；3:缩到合适 */
        cur = 32649, /* 鼠标指针，_IDC_ 开头的常量。 */
        img = imgs[37], /* 正常状态下，图像 */
        checkedimg = imgs[97], /* 元素被选择时，图像 */
    }, {
        type = "rect", 
        rectf = {x = 300;y = 8;width = 60;height = 24}, 
        width = 1, /* 边框宽度。为0则无边框。  */
        round = 14, /* 圆角半径。0为矩形，-1为椭圆，其他值(>0)为圆角矩形。 */
        cur = 32649, /* 鼠标指针，_IDC_ 开头的常量。 */
        fillcolor = 0xFFFF7F50, /* 正常状态下，填充颜色 */
        hoverfillcolor = 0xFFDA70D6 /* 鼠标划过项目时，填充颜色 */
    }, {
        type = "text",
        name = "delete", 
        click = true; 
        rectf = {x = 300;y = 12;width = 60;height = 20},
        align = 1, /* 文本水平对齐方式。0、(近端)左对齐  1、居中  2、(远端)右对齐 */
        valign = 1, /* 文本垂直对齐方式。0、(近端)顶对齐  1、居中  2、(远端)底对齐 */
        cur = 32649, /* 鼠标指针，_IDC_ 开头的常量。 */
        text = "删除";
        font = {name = "宋体", h = 13, color = 0xFFFFFFFF} /* 正常状态下字体 */
    } {
        type = "line",
        x1 = 0; /* 开始点x坐标 */
        y1 = 0; /* 开始点y坐标 */
        x2 = 380; /* 结束点x坐标 */
        y2 = 0; /* 结束点y坐标 */
        color = pen_black, /* 正常状态下，线条颜色。默认值：黑色 */
    } {
        type = "paint", /* 类型：paint，处理过程第一个参数为 godking.paint 对象 */
        proc = function(paint, itemIndex, elemIndex, rectF, disabled, checked, hovered, itemSelected, itemHovered) {
            paint = toPaint(paint); /* 绑定paint智能提示 */
            var age = tonumber(cp.itemList[itemIndex].age);
            var left = 200*dpi;
            var x = left + age*dpi;
            var y = rectF.y + 20*dpi;
            var rect = ::RECTF(x-60*dpi, y-10*dpi ,40*dpi,18*dpi);
            var points = {{x-50*dpi,y-10*dpi},{x-50*dpi,y+8*dpi},{x-10*dpi,y}};
            var fonth = 12*dpi;
            if age > 50 {
                paint.fillPolygon(points,0x8832CD32);
                paint.fillRoundRectF(rect, 10*dpi /*圆角半径*/ , 0xFF32CD32);
                paint.drawTextF(rect, "大龄", ::LOGFONT(name = "宋体"; h = fonth; color = 0xFFFFFFFF; brush = null), 0, 1, 2)
            }
            else if age < 40 {
                paint.fillPolygon(points,0x88FFD700);
                paint.fillRoundRectF(rect, 10 /*圆角半径*/ , 0xFFFFD700);
                paint.drawText(rect, "少年", ::LOGFONT(name = "宋体"; h = fonth; color = 0xFFFFFFFF; brush = null), 0, 1, 2)
            }
            else {
                paint.fillPolygon(points,0x884169E1);
                paint.fillRoundRectF(rect, 10 /*圆角半径*/ , 0xFF4169E1);
                paint.drawText(rect, "正常", ::LOGFONT(name = "宋体"; h = fonth; color = 0xFFFFFFFF; brush = null), 0, 1, 2)
            }
            if itemIndex > 1 {
                var x1 = left + tonumber(cp.itemList[itemIndex - 1].age)*dpi;
                var y1 = rectF.y - 20*dpi;
                paint.drawLine(x1, y1, x, y, pen_red);
            }
            if itemIndex < cp.itemCount {
                var x2 = left + tonumber(cp.itemList[itemIndex + 1].age)*dpi;
                var y2 = rectF.y + 60*dpi;
                paint.drawLine(x, y, x2, y2, pen_red);
            }
            paint.fillEllipse(x - 10*dpi, y - 10*dpi /*y1*/ , /*x2*/ x + 10*dpi, y + 10*dpi /*y2*/ , 0xFF8A2BE2);
            paint.drawText(x - 10*dpi, y - 10*dpi /*y1*/ , /*x2*/ x + 11*dpi, y + 12*dpi /*y2*/ , tostring(age), ::LOGFONT(name = "宋体"; h = 13*dpi; color = 0xFFFFFFFF; brush = null), 0, 1, 1);
        };
    }
}

cp = godking.customPlus(winform.plus, itemModel, itemList, {
    itemWidth = 380, /*项目最小宽度，为0时根据colnum自动计算，所以不能与colnum同时=0*/
    itemHeight = 40, /*项目最小高度，为0时根据rownum自动计算，所以不能与rownum同时=0*/
    autoSizeWidth = false, /*为true则自动将项目总宽度拉伸填满plus宽度，每个项目宽度不小于itemWidth*/
    autoSizeHeight = false, /*为true则自动将项目总高度拉伸填满plus高度，每个项目高度不小于itemHeight*/
    rownum = 0, /*项目行数，为0时根据itemHeight自动计算，所以不能与itemHeight同时=0*/
    colnum = 1, /*项目列数，为0时根据itemWidth自动计算，所以不能与itemWidth同时=0*/
    padLeft = 0, /*plus左边空白距离*/
    padTop = 0, /*plus顶边空白距离*/
    padRight = 0, /*plus右边空白距离*/
    padBottom = 0, /*plus底边空白距离*/
    autoFit = false, /*是否自动调整plus组件宽度或高度（其中之一），保证能刚好显示全部行或列*/
    vertical = false, /*是否将项目设置为竖向排列，行滚动方向设置为横向*/
    bkcolor = 0xFFFFFFFF, /*背景颜色*/
    bkimg = null, /*背景图像*/
    singleCheck = 0, /*元素check单选模式。0:多选；1:每个项目内单选；2:整个列表单选*/
})

cp.onClick = function(itemIndex /*项目索引*/ , elemIndex /*元素索引*/ , elemID /*元素id*/ , elemName /*元素name*/ , pageIndex /*当前页项目索引*/ , x /*鼠标X坐标*/ , y /*鼠标Y坐标*/ , disabled /*项目是否禁用*/ , itemRect /*项目区域*/ , elemRect /*元素区域*/ ) {
    select (elemName) {
        case "name" {
            import process;
            process.execute("https://aardio.online/?"++cp.itemList[elemIndex].name);
        }
        case "delete" {
            win.msgbox("您点击了按钮："++itemIndex++"，即将删除该项！");
            cp.delItem(itemIndex);
            cp.update();
        }
    }
}

for (i = 1; 100; 1) {
	//设置性别图片
    var sex, bk = math.random(0, 1) ? imgs[11] : imgs[18];
    if sex === imgs[11] { //对某个性别的项目改变背景色
        bk = 0xFFF0d8Eb;
    }
    //设置项目数据
    cp.addItem({
        logo = imgs[i];
        name = "客户"++i++"链接";
        sex = sex;
        age = tostring(math.random(30, 60));
        bk = {
            fillcolor = bk;
            itemhoverfillcolor = 0xFFFFF8DC;
        };
    })
}

var logo = ..gdip.bitmap("https://aardio.online/upload/attach/202501/2_AJ4VT9HQ52XUQBR.png");
cp.onDrawItemEnd = function(paint/*paint对象*/,itemIndex/*项目索引*/,itemIndexInPage/*项目在当前页内的索引*/,itemRectF/*项目区域*/){
    /*一个项目绘制结束时，触发该事件。事件内绘制与proc元素绘制的区别是：事件无区域，不影响各元素焦点处理*/
    paint = toPaint(paint); /*绑定paint对象的智能提示，方便输入后续代码*/
    if itemIndexInPage<5 {
        paint.drawImage(0/*x1*/,0/*y1*/,/*x2*/150*dpi,150*dpi/*y2*/,logo/*图片*/,0.8/*透明度或图片属性*/,/*保持比例*/);
    }
}

cp.bindScrollbar(winform.scrollbar);
cp.update();
win.loopMessage();

我想用这个库做个【弹出列表】，但是做为子窗口，不知为何它会跑到旁边去？

import win.ui;
import fonts.fontAwesome
/*DSG{{*/
var winform = win.form(text="aardio form";right=414;bottom=75)
winform.add(
button={cls="button";text="添加项目";left=145;top=20;right=265;bottom=62;z=3};
button2={cls="button";text="显示菜单";left=20;top=20;right=140;bottom=62;z=2};
button3={cls="button";text="删除项目";left=270;top=20;right=390;bottom=62;z=4};
plus={cls="plus";left=26;top=85;right=221;bottom=447;bgcolor=32768;hide=1;notify=1;z=1};
scrollbar={cls="scrollbar";left=217;top=76;right=237;bottom=446;edge=1;hide=1;z=5}
)
/*}}*/

import crypt.bin;

var base64Str = "iVBORw0KGgoAAAANSUhEUgAAABAAAAAQCAYAAAAf8/9hAAAACXBIWXMAAAsTAAALEwEAmpwYAAAABGdBTUEAALGOfPtRkwAAACBjSFJNAAB6JQAAgIMAAPn
/AACA6QAAdTAAAOpgAAA6mAAAF2+SX8VGAAACmUlEQVR42mL8//8/K8P/P2kMf745MDD8Z2IAEgz4ASNYCavAxX379s0GCCAWoEAuw7tzvQy/3gClmFGV/oeaxciIJv6XgYFPPIi
R4Z80QACxMPz7bQrW/O8nxHBkRRziQCFWBobvT9AMBxr86wNIjTxAALHABUAakMG/PwwM3IoMDMycDAzfHoIEkCz4D+YDHcgIEEBMENM+MjD8/QH1HpD/F+gaVj4GBnYxBgY2IaBL
JCBi//4hqfkBNggggCAueH2IgeHHcwYGTlmgYqAmdhEGBhFLBgYmVoiFvKoMDJ9vAdU8Blr2FoI5gC7758kAEEAQA34DXcADVCTpCdQsCnS6HCiUEd7hkGRgkIsAegVowM/XDAwvd
gPD5QpYCiCAmMBO+gqUeLkH6AKgQgE9VM0wwMIDDHlNiGs+XgIa8BwcDgABBDGACeinjxcZGE54MzC8P4E7BXy7w8BwKhDogk3AMHgPFgIIICYwyQyMIk42oIEvGBiupzAw/HmHRT
cwlm4VAW0+w8DAxQ10JSR8AAIIYgALkGIDBgcnOxADncrEjsUAkCUCkMBjB7JZIekCIICYwFHLAuSwgTDQK0LmQAO4IXq+HwU6Gxhg/39B+ALGQAOAFrGyQPQAAUAAsQDjlBHsAla
oITz6QC8AE87HSUADtgKVABMUhyMDA38B0AXAhMXBBTGQBeJ4gABiYWBk+sHAArSZ+TvQAKATvy0DRlUPUAEwarm5IL78s4OB4c0BYBgBDWAD8n8BExHrPwYmZub/AAHEsmv3waW2
+snhnCy6HAxsQL+zAg1js4CGA3LeANr6+yfEGz9B+UaLYf/KU+cAAgiswi8g1FFDXc3z969fzNCMgTsng5zNysJy7frNe1s3r18MEGAAK7S6z0orwGoAAAAASUVORK5CYII=";
var bmpBase64 = crypt.bin.decodeBase64(base64Str); //base64编码解码为图片

var itemModel = {
	{	// 项目背景
		type="rect",
		name="rect";
		click=true;  // 是否响应鼠标点击事件
		rectf={x=0;y=0;width=0;height=0},
		width=1;
		color = 0x88FFFFFF;
		fillcolor=0xFFdcd3b2,
		itemhoverfillcolor=0xFF9d896c,
		cur=32649/*_IDC_HAND*/;
	},
	{
		name="logo",
		type="img",
		cur=32649/*_IDC_HAND*/;
		rectf={x=5;y=5;width=30;height=40},
        scale=true,  // 按比例缩放
 	},
	{
		name="title",
		type="text",
		cur=32649/*_IDC_HAND*/;
		rectf={x=40;y=0;width=-1;height=40},
		align=0;
		valign=1;		
		font={name="宋体",h=14,color=0xFFFF5555,bold=true},
		itemhoverfont={name="宋体",h=14,color=0xFFFFFFFF},
	},	
	{
		name="title2",
		type="text",
		cur=32649/*_IDC_HAND*/;
		rectf={x=40;y=30;width=-1;height=20},
		align=0;
		valign=1;		
		font={name="宋体",h=12,color=0xFF999999},
		itemhoverfont={name="宋体",h=12,color=0xFFFFFFFF},
	},
}
 
itemList = {}
for(i=1;7;1){
	..table.push(itemList,	{
			logo = bmpBase64,
			title="菜单项目"++i,
			title2="我是副标题"++i
	})
}
 
import godking.customPlus
var p = godking.customPlus(winform.plus,itemModel,itemList,{
		itemWidth=200,	/*项目宽度*/ 
		itemHeight=50,	/*项目高度*/
		autoSizeRow=false,	/*自动根据项目行数及plus高度调整项目高度*/
		autoSizeCol=true,	/*自动根据项目列数及plus宽度调整项目宽度*/
		colnum=1, 	/*项目列数，为0则根据项目宽度和plus宽度自动计算*/
		rownum=0, 	/*项目行数，为0则根据项目高度和plus高度自动计算*/
		padLeft=0,	/*plus左边空白距离*/
		padTop=0,	/*plus顶边空白距离*/
		padRight=0,	/*plus右边空白距离*/
		padBottom=0,	/*plus底边空白距离*/		
		
		});
		
p.onClick = function(itemIndex/*项目索引*/,elemIndex/*元素索引*/,elemID/*元素id*/,elemName/*元素name*/,pageIndex/*当前页项目索引*/){
	p.hide();
	
	..win.msgbox(itemList[itemIndex].title);
}
 
winform.button2.oncommand = function(id,event){
	p.show();
	winform.scrollbar.hide = false;
	p.setPos(owner.left,owner.bottom);
}
 
winform.button.oncommand = function(id,event){
	p.addItem({
			logo = bmpBase64,
			title="菜单项目"++p.itemCount+1,
			title2="我是副标题"++p.itemCount+1
	});
	p.update()
}
 
winform.button3.oncommand = function(id,event){
	p.delItem(-1);
	p.update()
}
 
 

p.bindScrollbar(winform.scrollbar); 

winform.plus.orphanWindow()
winform.scrollbar.orphanWindow()



winform.show();
win.loopMessage();

import win.ui;
import fonts.fontAwesome
/*DSG{{*/
var winform = win.form(text="aardio form";right=414;bottom=75)
winform.add(
button={cls="button";text="添加项目";left=145;top=20;right=265;bottom=62;z=3};
button2={cls="button";text="显示菜单";left=20;top=20;right=140;bottom=62;z=2};
button3={cls="button";text="删除项目";left=270;top=20;right=390;bottom=62;z=4};
plus={cls="plus";left=280;top=136;right=480;bottom=528;bgcolor=32768;dl=1;dt=1;notify=1;z=1};
scrollbar={cls="scrollbar";left=480;top=136;right=504;bottom=528;dl=1;dt=1;edge=1;z=5};
static={cls="static";left=280;top=136;right=504;bottom=528;bgcolor=16777215;hide=1;transparent=1;z=6}
)
/*}}*/

import crypt.bin;

var base64Str = "iVBORw0KGgoAAAANSUhEUgAAABAAAAAQCAYAAAAf8/9hAAAACXBIWXMAAAsTAAALEwEAmpwYAAAABGdBTUEAALGOfPtRkwAAACBjSFJNAAB6JQAAgIMAAPn
/AACA6QAAdTAAAOpgAAA6mAAAF2+SX8VGAAACmUlEQVR42mL8//8/K8P/P2kMf745MDD8Z2IAEgz4ASNYCavAxX379s0GCCAWoEAuw7tzvQy/3gClmFGV/oeaxciIJv6XgYFPPIi
R4Z80QACxMPz7bQrW/O8nxHBkRRziQCFWBobvT9AMBxr86wNIjTxAALHABUAakMG/PwwM3IoMDMycDAzfHoIEkCz4D+YDHcgIEEBMENM+MjD8/QH1HpD/F+gaVj4GBnYxBgY2IaBL
JCBi//4hqfkBNggggCAueH2IgeHHcwYGTlmgYqAmdhEGBhFLBgYmVoiFvKoMDJ9vAdU8Blr2FoI5gC7758kAEEAQA34DXcADVCTpCdQsCnS6HCiUEd7hkGRgkIsAegVowM/XDAwvd
gPD5QpYCiCAmMBO+gqUeLkH6AKgQgE9VM0wwMIDDHlNiGs+XgIa8BwcDgABBDGACeinjxcZGE54MzC8P4E7BXy7w8BwKhDogk3AMHgPFgIIICYwyQyMIk42oIEvGBiupzAw/HmHRT
cwlm4VAW0+w8DAxQ10JSR8AAIIYgALkGIDBgcnOxADncrEjsUAkCUCkMBjB7JZIekCIICYwFHLAuSwgTDQK0LmQAO4IXq+HwU6Gxhg/39B+ALGQAOAFrGyQPQAAUAAsQDjlBHsAla
oITz6QC8AE87HSUADtgKVABMUhyMDA38B0AXAhMXBBTGQBeJ4gABiYWBk+sHAArSZ+TvQAKATvy0DRlUPUAEwarm5IL78s4OB4c0BYBgBDWAD8n8BExHrPwYmZub/AAHEsmv3waW2
+snhnCy6HAxsQL+zAg1js4CGA3LeANr6+yfEGz9B+UaLYf/KU+cAAgiswi8g1FFDXc3z969fzNCMgTsng5zNysJy7frNe1s3r18MEGAAK7S6z0orwGoAAAAASUVORK5CYII=";
var bmpBase64 = crypt.bin.decodeBase64(base64Str); //base64编码解码为图片

var itemModel = {
    {    // 项目背景
        type="rect",
        name="rect";
        click=true;  // 是否响应鼠标点击事件
        rectf={x=0;y=0;width=0;height=0},
        width=1;
        color = 0x88FFFFFF;
        fillcolor=0xFFdcd3b2,
        itemhoverfillcolor=0xFF9d896c,
        cur=32649/*_IDC_HAND*/;
    },
    {
        name="logo",
        type="img",
        cur=32649/*_IDC_HAND*/;
        rectf={x=5;y=5;width=30;height=40},
        scale=true,  // 按比例缩放
     },
    {
        name="title",
        type="text",
        cur=32649/*_IDC_HAND*/;
        rectf={x=40;y=0;width=-1;height=40},
        align=0;
        valign=1;        
        font={name="宋体",h=14,color=0xFFFF5555,bold=true},
        itemhoverfont={name="宋体",h=14,color=0xFFFFFFFF},
    },    
    {
        name="title2",
        type="text",
        cur=32649/*_IDC_HAND*/;
        rectf={x=40;y=30;width=-1;height=20},
        align=0;
        valign=1;        
        font={name="宋体",h=12,color=0xFF999999},
        itemhoverfont={name="宋体",h=12,color=0xFFFFFFFF},
    },
}
 
itemList = {}
for(i=1;30;1){
    ..table.push(itemList,    {
            logo = bmpBase64,
            title="菜单项目"++i,
            title2="我是副标题"++i
    })
}

import godking.customPlus
var p = godking.customPlus(winform.plus,itemModel,itemList,{
        itemWidth=200,    /*项目宽度*/ 
        itemHeight=50,    /*项目高度*/
        autoSizeRow=true,    /*自动根据项目行数及plus高度调整项目高度*/
        autoSizeCol=true,    /*自动根据项目列数及plus宽度调整项目宽度*/
        colnum=1,     /*项目列数，为0则根据项目宽度和plus宽度自动计算*/
        rownum=0,     /*项目行数，为0则根据项目高度和plus高度自动计算*/
        padLeft=0,    /*plus左边空白距离*/
        padTop=0,    /*plus顶边空白距离*/
        padRight=0,    /*plus右边空白距离*/
        padBottom=0,    /*plus底边空白距离*/ 
        });
p.onClick = function(itemIndex/*项目索引*/,elemIndex/*元素索引*/,elemID/*元素id*/,elemName/*元素name*/,pageIndex/*当前页项目索引*/){
    winform.static.show(false);
    ..win.msgbox(itemList[itemIndex].title);
}
 
winform.button2.oncommand = function(id,event){
	var w = winform.plus.width;
	if p.itemCount>7 {
		winform.plus.height=350 +1
		winform.static.width = winform.plus.width + winform.scrollbar.width +1
	} else {
		winform.plus.height=p.itemCount*50 +1 
		winform.static.width = winform.plus.width +1
	}
	winform.scrollbar.height = winform.plus.height
    var x,y = ..win.toScreen(owner.hwnd);
    winform.static.setPos(x,y+owner.height);
    winform.static.show(true);
}
 
winform.button.oncommand = function(id,event){
    p.addItem({
            logo = bmpBase64,
            title="菜单项目"++p.itemCount+1,
            title2="我是副标题"++p.itemCount+1
    });
    p.update()
}
 
winform.button3.oncommand = function(id,event){
    p.delItem(-1);
    p.update()
}
 
winform.plus.setParent(winform.static)
winform.scrollbar.setParent(winform.static)
p.bindScrollbar(winform.scrollbar); 
winform.static.orphanWindow()

winform.show();
win.loopMessage();