请升级虚表最新版：

import win.ui;
import godking.vlistEx;
/*DSG{{*/
mainForm = win.form(text="vlistEx - table adapter";right=743;bottom=447)
mainForm.add(
vlist={cls="vlistEx";left=10;top=10;right=736;bottom=440;db=1;dl=1;dr=1;dt=1;edge=1;transparent=1;z=1}
)
/*}}*/

mainForm.show();
var t = { fields={"序号","姓名","年龄","地址","身份证"} };
for(i=1;100;1){
    var tt={};
    tt["序号"]="[@rowindex]";  // 行序号标记是不允许编辑修改的
    tt["姓名"]="["+string.random(math.random(1,20))+"]";
    tt["年龄"]="["+string.random(math.random(1,20))+"]";
    tt["地址"]="["+string.random(math.random(1,20))+"]";
    tt["身份证"]="["+string.random(math.random(1,20))+"]";
    ..table.push(t,tt);
}
mainForm.vlist.setTable(t);
mainForm.vlist.setColWidthFit();

//允许编辑
mainForm.vlist.onEditBegin = true
//显示前隐藏前后 [ ]
mainForm.vlist.beforeEditBoxShow = function(row,col,edit){
	edit.text = ..string.trim(edit.text,'[]')
}
//显示后调整光标位置
mainForm.vlist.onEditBoxShow = function(row,col,edit){
	edit.text = ..string.trim(edit.text,'[]')
	if col===2 { // 第2列全选
		edit.selectAll();
	} elseif col===3 { // 第3列光标到最前
		edit.setsel()
	} // 其他的不设置，默认光标到最后
}
//编辑完毕再加上前后 [ ]
mainForm.vlist.onEditEnd = function(row/*行*/,col/*列*/,text/*内容*/,endType/*结束类型*/){
	return "["+text+"]"; 
}
//设置为编辑框全选,执行时间在onEditBoxShow后。因为在onEditBoxShow进行调整，这里不设置了。
//mainForm.vlist.editBoxSelectAll = true

win.loopMessage();